Pomoc.

[Hasumi]

Czesc. Zaczynam sie bawic w AutoIT.

Moze mi ktos powiedziec jak zrobic prosty pobierator jednego pliku .exe?

 

Szukalem na internecie i w gotowych scryptach ale nie znalazlem.

[JeBroer]

Co dokładniej ma w tym być.

Ma co jakiś czas ściągać sam, i czy to będzie jeden plik z danego miejsca i tylko jeden ten sam plik non stop ?

Ja ci nie za dużo pomogę lecz innym chętnym przydadżą się takie informacje.

[Hasumi]

Chodzi o pobieranie tego samego pliku.

[wefhy]

inetget

[karolkarol21621]

download z progresem...

Func download1($link, $sciezka)
$download1 = InetGet($link, $sciezka, 1, 1)
$size = InetGetSize($link, 1)
Sleep(1000)

ProgressOn("Pobieranie", "", "")
While InetGetInfo($download1, 2) = False
$speed = InetGetInfo($download1, 0) / 1024
ProgressSet((InetGetInfo($download1, 0) / $size) * 100, $speed & "kb " & " / " & $size / 1000)
Sleep(100)
WEnd
ProgressOff()
EndFunc ;==>download1

[jackraymund]

lepiej winhttp użyć, 3 razy szybciej się ściąga, ponieważ inetget używa internet explorera(jak ktoś niema go na kompie to jest lipa dodatkowa)

 

 

#include "WinHttp.au3"
#include "timers.au3"
Opt("MustDeclareVars", 1)

Global $sHost = "www.mpcforum.pl"
Global $sTarget = "/uploads/images/1358509315-U29883.jpg"
Global $sDestination = @ScriptDir & "\CatHot.jpg"
Global $hHttpOpen = _WinHttpOpen()
If @error Then
MsgBox(48, "Error", "Error initializing the usage of WinHTTP functions.")
Exit 1
EndIf
Global $hHttpConnect = _WinHttpConnect($hHttpOpen, $sHost)
If @error Then
MsgBox(48, "Error", "Error specifying the initial target server of an HTTP request.")
_WinHttpCloseHandle($hHttpOpen)
Exit 2
EndIf
for $i = 1 to 10
Local $czas = _Timer_Init()
Global $hHttpRequest = _WinHttpOpenRequest($hHttpConnect, Default, $sTarget)
If @error Then
MsgBox(48, "Error", "Error creating an HTTP request handle.")
_WinHttpCloseHandle($hHttpConnect)
_WinHttpCloseHandle($hHttpOpen)
Exit 3
EndIf
_WinHttpSendRequest($hHttpRequest)
If @error Then
MsgBox(48, "Error", "Error sending specified request.")
_WinHttpCloseHandle($hHttpConnect)
_WinHttpCloseHandle($hHttpOpen)
Exit 4
EndIf
_WinHttpReceiveResponse($hHttpRequest)
Global $bChunk, $bData, $hFile
If _WinHttpQueryDataAvailable($hHttpRequest) Then
While 1
$bChunk = _WinHttpReadData($hHttpRequest, 2) ; read binary
If @error Then ExitLoop
$bData = _WinHttpBinaryConcat($bData, $bChunk) ; concat two binary data
WEnd
; Save it to the file
$hFile = FileOpen($sDestination, 26)
FileWrite($hFile, $bData)
FileClose($hFile)
Else
MsgBox(48, "Error occurred", "No data available. " & @CRLF)
EndIf
consolewrite(int(_Timer_Diff($czas))& @CRLF)
Next
_WinHttpCloseHandle($hHttpRequest)
_WinHttpCloseHandle($hHttpConnect)
_WinHttpCloseHandle($hHttpOpen)

na 10 testów

czasy wyszły

 

171
86
46
49
46
50
46
53
47
54

w inet get ten sam plik

 

#include "timers.au3"
for $i = 1 to 10
Local $czas = _Timer_Init()
Local $hDownload = InetGet("http://www.mpcforum.pl/uploads/images/1358509315-U29883.jpg", @ScriptDir & "\update.jpg", 1, 1)
Do
Sleep(250)
Until InetGetInfo($hDownload, 2) ; Check if the download is complete.
consolewrite(int(_Timer_Diff($czas))& @CRLF)
Next

 

261
257
257
257
257
257
250
257
257
257

 

47 ms a 250 to jest duża różnica

 

przy wiekszych plikach

 

winhttp

6116
5739
5882
5597
5578

inetget
6384
6134
7815
5992
5965

[Hasumi]

Super panowie wielkie dzieki!

 

Nie mam biblioteki czy jak ?

 

[karolkarol21621]

tak error dotyczy braku include

wrzuciles biblioteke do: \AutoIt3\Include?

[Hasumi]

Dalem tak i tak ale wychodzi w winhttp blad

 

Chyba wiem

 

 

 

Edit

 

Moze mi ktos podeslac ta biblioteke.

 

[karolkarol21621]

https://dl.dropbox.com/s/oy2huxk9zkvxlrm/WinHttp.au3?dl=1

[jackraymund]

#include "WinHttp.au3"
#include "timers.au3"
Opt("MustDeclareVars", 1)
global $data
Global $bChunk, $bData = "", $hFile
local $iContentLength = 0
Global $sHost = "imperiumtapet.pl"
Global $sTarget = "site_media/wallpaper/42472/image/bc9b95f43a74bb6c6d34.bmp"
Global $sDestination = @ScriptDir & "\CatHot.bmp"
Global $hHttpOpen = _WinHttpOpen()
If @error Then
MsgBox(48, "Error", "Error initializing the usage of WinHTTP functions.")
Exit 1
EndIf
Global $hHttpConnect = _WinHttpConnect($hHttpOpen, $sHost)
If @error Then
MsgBox(48, "Error", "Error specifying the initial target server of an HTTP request.")
_WinHttpCloseHandle($hHttpOpen)
Exit 2
EndIf
Global $hHttpRequest = _WinHttpOpenRequest($hHttpConnect, "GET", $sTarget)
_WinHttpSendRequest($hHttpRequest)
_WinHttpReceiveResponse($hHttpRequest)
$bdata = ""
$iContentLength = _WinHttpQueryHeaders($hHttpRequest, $WINHTTP_QUERY_CONTENT_LENGTH)
While 1
$bChunk = _WinHttpReadData($hHttpRequest,2,$iContentLength) ; read binary
If @error Then ExitLoop
$bData = _WinHttpBinaryConcat($bData, $bChunk) ; concat two binary data
WEnd
$hFile = FileOpen($sDestination, 26)
FileWrite($hFile, $bData)
FileClose($hFile)
_WinHttpCloseHandle($hHttpRequest)
_WinHttpCloseHandle($hHttpConnect)
_WinHttpCloseHandle($hHttpOpen)

tamtego kodu nie używaj, bo ściąga po 8000bajtow, przez co zamula, i się czas wydłuża, tutja poprawilem aby na raz ściągnęło

[Hasumi]

 

 

Chyba znowu mi brakuje tej biblioteki :/

[jackraymund]

http://code.google.c.../downloads/list

tu masz pelna biblie z helpem

[karolkarol21621]

sory za offtop ale czy da sie wrzucic tego helpa z winhttp do tego ogolnego z autoit?

[Hasumi]

Super zarabiscie dzieki wszystkim