[Q]PNG w Gui

[TheAlsenPL]

#include <GUIConstants.au3>

$Form1 = GUICreate("SyrenBot", 290, 306, 193, 125)
$Logo = GUICtrlCreatePic("logo.png", 18, 8, 249, 100)
$Button1 = GUICtrlCreateButton("Spambot", 16, 128, 249, 65, 0)
$Button2 = GUICtrlCreateButton("Bot", 16, 216, 249, 65, 0)
GUISetState(@SW_SHOW)

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit

EndSwitch
WEnd

 

Tak wygląda główne menu mojego Bota. Logo znajduje się w folderze z programem.

Próbowałem również ze ścieżką czyli:

$Logo = GUICtrlCreatePic("C:\logo.png", 18, 8, 249, 100)

 

Również nie działało.

Co robię nie tak?

[4ggr35510n]

Otwórz helpa ( [F1] ).

Wyszukaj frazy "png".

 

Znajdzie ci art o funkcji której korzystasz - GuiCtrlCreatePic.

Wciśnij CTRL + F i jeszcze raz ( w tym arcie ) wyszukaj frazy "png".

 

Zapoznaj się z dostarczonym przykładem.

[Phoenix_PL]

A próbowałeś testować flagę błędu (@error) żeby się dowiedzieć czy program 'niby' stworzył tę fotkę, tylko coś poszło nie tak gdzie indziej?

Debbugingu (chyba tak to się nazywa :P) się poducz Bardzo ci to pomoże.

 

APO: Wszystko jest opisane w Helpie tej funkcji

 

PNG can be used with GDI+. See example 3.

 

Przykład 3 z helpa:

;----- example 3 PNG work araund by Zedna
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GDIPlus.au3>
#include <WinAPI.au3>

Global $hGUI, $hImage, $hGraphic, $hImage1

; Create GUI
$hGUI = GUICreate("Show PNG", 250, 250)

; Load PNG image
_GDIPlus_Startup()
$hImage = _GDIPlus_ImageLoadFromFile("..\GUI\Torus.png")
$hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)

GUIRegisterMsg($WM_PAINT, "MY_WM_PAINT")
GUISetState()

; Loop until user exits
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

; Clean up resources
_GDIPlus_GraphicsDispose($hGraphic)
_GDIPlus_ImageDispose($hImage)
_GDIPlus_Shutdown()

; Draw PNG image
Func MY_WM_PAINT($hWnd, $msg, $wParam, $lParam)
   #forceref $hWnd, $Msg, $wParam, $lParam
   _WinAPI_RedrawWindow($hGUI, 0, 0, $RDW_UPDATENOW)
   _GDIPlus_GraphicsDrawImage($hGraphic, $hImage, 0, 0)
   _WinAPI_RedrawWindow($hGUI, 0, 0, $RDW_VALIDATE)
   Return $GUI_RUNDEFMSG
EndFunc   ;==>MY_WM_PAINT

 

Tyle w tym temacie.

[TheAlsenPL]

A bmp powinno dzialac normalnie?

[KingSP1MPC]

z folderu examples ,z objaśnieniami.

#include <GDIPlus.au3>
#include <GuiConstantsEx.au3>

; ===============================================================================================================================
; Description ...: Shows how to display a PNG image
; Author ........: Paul Campbell (PaulIA)
; Notes .........:
; ===============================================================================================================================

; ===============================================================================================================================
; Global variables
; ===============================================================================================================================
Global $hGUI, $hImage, $hGraphic

; Create GUI
$hGUI = GUICreate("Show PNG", 240, 240)
GUISetState()

; Load PNG image
_GDIPlus_Startup()
$hImage = _GDIPlus_ImageLoadFromFile("..\Torus.png")

; Draw PNG image
$hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
_GDIPlus_GraphicsDrawImage($hGraphic, $hImage, 0, 0)

; Loop until user exits
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

; Clean up resources
_GDIPlus_GraphicsDispose($hGraphic)
_GDIPlus_ImageDispose($hImage)
_GDIPlus_Shutdown()

[TheAlsenPL]

Dobra do zamknięcia.