Tworzenie pola do wpisywania bez DialogBox?

[RoaDevil]

Witam wszystkich!

Czy istnieje możliwość stworzenia samego pola INPUT pojawiającego się na ekranie, na danej pozycji bez okienka z kontrolkami?

#include <GUIConstantsEx.au3>

GUICreate("Kontrolki GUI", 400, 600)
GUICtrlCreateInput("Okienko wprowadzania", 235, 255, 130, 20)
GUISetState()
MsgBox(0,"","")

Z góry dziękuję za odpowiedź jak to można zrobić.

Pozdrawiam!

[Pawellek]

InputBox

Example:

#include <MsgBoxConstants.au3>

Example()

Func Example()
    ; Places the input box in the top left corner displaying the characters as they
    ; are typed.
    Local $sAnswer = InputBox("Question", "Where were you born?", "Planet Earth", "", _
             - 1, -1, 0, 0)

    ; Display the result.
    MsgBox($MB_SYSTEMMODAL, "", $sAnswer)

    ; Asks the user to enter a password.  Don't forget to validate it!
    Local $sPasswd = InputBox("Security Check", "Enter your password.", "", "*")

    ; Display the result.
    MsgBox($MB_SYSTEMMODAL, "", $sPasswd)

    ; Asks the user to enter a 1 or 2 character response.  The M in the password
    ; field indicates that empty string is not accepted and the 2 indicates that the
    ; responce will be at most 2 characters long.
    Local $sValue = InputBox("Testing", "Enter the 1 or 2 character code.", "", " M2")

    ; Display the result.
    MsgBox($MB_SYSTEMMODAL, "", $sValue)
EndFunc   ;==>Example

 

[RoaDevil]

Dziękuję bardzo za odpowiedź, ale chyba źle opisałem o co mi chodzi.

Chodzi o samo pole do wpisania tekstu. bez żadnego dialog box. bez paska nawet z ikonką zamykania. i bez tła aplikacji. Sam samiusieńki input. Tak jakby sam biały prostokącik do wpisania tekstu w nim.

[RoaDevil]

Stworzyć okienko bez paska z kontrolkami. Coś w stylu c++ : BorderStyle = bsNone; Tylko jak stworzyć okienko bez paska na górze w AutoIt?

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Example4() ; With Re-Sizing & No TaskBar.

Func Example4() ; With Re-Sizing & No TaskBar.
    Local $hGUI = GUICreate('GUI With Only Close4', 250, 250, -1, -1, BitXOR(0,0,0), -1, WinGetHandle(AutoItWinGetTitle()))
    GUISetState(@SW_SHOW, $hGUI)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

        EndSwitch
    WEnd
    GUIDelete($hGUI)
EndFunc   ;==>Example4

Taki kod tworzy okno bez kontrolek, ale paskiem którego miałoby nie być

(chciałbym sam kwadracik szary bez niebieskiej obwódki na około z napisem "GUI With Only Close4"):

 

[Pawellek]

#include <GuiConstants.au3>
#include <WindowsConstants.au3>

OnlyInput() ; Only InputBox

Func OnlyInput()
	Local $hGUI = GUICreate('', 150, 20, -1, -1, $WS_POPUP)
	Local $hInput = GUICtrlCreateInput("", 0, 0, 150, -1, -1, -1)
	GUISetState(@SW_SHOW, $hGUI)

	While 1
		Switch GUIGetMsg()
			Case $hInput
				MsgBox(0, "OnlyInput()", "The Enter Key was pressed, text in input:" & @CRLF & GUICtrlRead($hInput))
				ExitLoop
		EndSwitch
	WEnd
	GUIDelete($hGUI)
EndFunc   ;==>OnlyInput

 

[RoaDevil]

Dziękuję bardzo! Jesteśmy blisko celu a mianowicie Twój kod tworzy inputa, który w rogach ma kolor tła okna. (załączam obrazki)

a taj w powiększeniu:

Chce osiągnąć inputa czysto białego (albo kolor wg uznania).

Ten trzeci ma ramkę już bez widocznego koloru tła ($WS_EX_STATICEDGE), ale chciałbym się jeszcze pozbyć również szarej ramki.
Nie mam pojęcia, który styl za to odpowiada;/ https://www.autoitscript.com/autoit3/docs/appendix/GUIStyles.htm

#include <GuiConstants.au3>
#include <WindowsConstants.au3>

OnlyInput() ; Only InputBox

Func OnlyInput()
	Local $hGUI = GUICreate('', 150, 20, -1, -1, $WS_POPUP, $WS_EX_TOPMOST)
	GUISetBkColor(0xFF0000, $hGUI)
	Local $hInput = GUICtrlCreateInput("", 0, 0, 150, -1, -1, $WS_EX_STATICEDGE)
	GUISetState(@SW_SHOW, $hGUI)

	While 1
		Switch GUIGetMsg()
			Case $hInput
				MsgBox(0, "OnlyInput()", "The Enter Key was pressed, text in input:" & @CRLF & GUICtrlRead($hInput))
				ExitLoop
		EndSwitch
	WEnd
	GUIDelete($hGUI)
EndFunc   ;==>OnlyInput

 

[Pawellek]

$WS_EX_TRANSPARENT

[RoaDevil]

I git Temat do zamknięcia.