Lista rozwijana (COMBO) - objaśnienie.

[miecho91]

Witam,

Czy jest ktoś w stanie mi objaśnić jak tym się posługiwać?

Umiem zrobić te GUI. Ale jeżeli chodzi o podpięcie czegoś pod nie to już wymiękam...

Chodzi mi dokładnie jak podpiąć funkcję.

Na wikibooks znalazłem kod..

#include <GUIConstants.au3>

Local $col=0xffffff, $col1=0

GUICreate("Kolor tła")
$hCombo=GUICtrlCreateCombo("Biały", 20, 20, -1, -1, $CBS_DROPDOWNLIST)  ; pierwsza pozycja listy
GUICtrlSetData(-1, "Czerwony|Zielony|Niebieski", "Biały") ;pozostałe pozycje oraz ustalenie pozycji domyślnej

GUISetState()
 
Do
   $msg = GUIGetMsg()
   Switch GUICtrlRead($hCombo)
      Case "Biały"
         $col = 0xffffff
      Case "Czerwony"
         $col = 0xff0000
      Case "Zielony"
         $col = 0x00ff00
      Case "Niebieski"
         $col = 0x0000ff
   EndSwitch
   If $col<>$col1 Then GUISetBkColor($col)  ;ustawienie koloru tła
   $col1 = $col
Until $msg = $GUI_EVENT_CLOSE

No okej zamiast kolorów podpinam funkcje. Niby ok ale.. parę uchybień się trafia. Po pierwsze - gdy najadę na listę - nie kliknę tylko najadę myszka - funkcja zaczyna od razu działać. Po drugie jak mam jakieś inne przyciski jak to wszystko połączyć, żeby to współgrało ze sobą.

[wasta]

Widzę, że używasz mojego podręcznika na Wikibooks. Bardzo mi miło, ze jest użyteczny.

Ale przejdźmy do twojego problemu. Masz tu przykład oparty na twoim drugim poście:

#include <GUIConstants.au3>
HotKeySet("{ESC}", "end")

$hForm1 = GUICreate("Form1", 202, 156, 192, 124)
$hLabel1 = GUICtrlCreateLabel("BOT PLEMIONA v1.0", 0, 8, 204, 17, 1)
$hButton1 = GUICtrlCreateButton("Farmienie", 25, 24, 75, 25)
$hButton2 = GUICtrlCreateButton("Wioski", 26, 48, 73, 25)
$hButton3 = GUICtrlCreateButton("Pausa", 104, 24, 75, 25)
$hButton4 = GUICtrlCreateButton("Koniec", 104, 48, 75, 25)
$hCombo=GUICtrlCreateCombo("Ilosc wiosek", 104, 100, 85, 21, $CBS_DROPDOWNLIST)  ; pierwsza pozycja listy
GUICtrlSetData(-1, "Wioska 2|Wioska 3|Wioska 4|Wioska 5", "Ilosc wiosek") ;pozostale pozycje oraz ustalenie pozycji domyslnej

GUISetState()
;==========================================
While 1
   $msg = GUIGetMsg()
   Select
      Case GUICtrlRead($hCombo)="Wioska 2" And $msg=$hCombo
		MsgBox(0,"","Wioska 2",1)
      Case GUICtrlRead($hCombo)="Wioska 3" And $msg=$hCombo
		MsgBox(0,"","Wioska 3",1)
      Case GUICtrlRead($hCombo)="Wioska 4" And $msg=$hCombo
		MsgBox(0,"","Wioska 4",1)
      Case GUICtrlRead($hCombo)="Wioska 5" And $msg=$hCombo
		MsgBox(0,"","Wioska 5",1)
	   Case $msg=$hButton1
		MsgBox(0,"","Farmienie",1)
	   Case $msg=$hButton2
		MsgBox(0,"","Wioski",1)
	   Case $msg=$hButton3
		MsgBox(0,"","Pauza",1)
	   Case $msg=$hButton4
		MsgBox(0,"","Koniec",1)
	   Case $msg = $GUI_EVENT_CLOSE
		Exit
   EndSelect
WEnd

;-----------------------------------------------
Func end()
	Exit
EndFunc

Chyba o to ci chodziło. Jak jeszcze nie to, to pisz.