SMTP problem

[Arturzt29]

Witam, mam taki kod:

 

#include <SMTP.au3> ;Include SMTP file

Global $ClearLogAfterEmail, $GmailUser, $GmailPass, $ToEmail ;Deklaracja zmiennych

$Tm = "DzienRoku " & @YEAR & " = " & @YDAY

$GmailUser = "mój adres email" ;Adres e-mail nadawcy(jednoczesnie uzytkownik)
$GmailPass = "hasło do email" ;Hasło do adresu e-mail nadawcy
$ToEmail = "inny adres email" ;Adres e-mail odbiorcy
$StmpServer = "smtp.gmail.com" ;Adres serwera stmp nadawcy
$Temat = $Tm ;Temat Maila
$Tresc = "Wyslano o godz " & @HOUR
$Nadawca = "WW" ;to zostanie wyswietlone w polu nadawca (Dowolny tekst)
$Zalacznik = "C:\log.txt" ;Sciezka do zalącznika
;Wysłanie maila
_INetSmtpMailCom($StmpServer, $Nadawca, $GmailUser, $ToEmail, $GmailUser, $GmailPass, $Temat, $Tresc,$Zalacznik)

 

Zaraz po uruchomieniu wyświetla się napis:

 

Error code:2 Description:Nie powiodło się połączenie warstwy transportu z serwerem.

Hasło i adres email wpisuję poprawne, co robię źle?

[hehe7]

>>> C:\Program Files\AutoIt3\Include zapisz jako SMTP.au3

 

 

    #cs
       I did nor wrote this script, i downloaded it from a user on the AutoIt official forums.
       I simple edited a small part of it.
       ~Marlo
    #ce

    #Include<file.au3>
    Global $oMyError = ObjEvent("AutoIt.Error", "MyErrFunc")
    #Include<file.au3>

    Global $oMyRet[2]

    Func _INetSmtpMailCom($s_SmtpServer, $s_FromName, $s_FromAddress, $s_ToAddress, $s_Username, $s_Password, $s_Subject = "", $as_Body = "", $s_AttachFiles = "", $s_CcAddress = "", $s_BccAddress = "", $IPPort=465, $ssl=1)
        $objEmail = ObjCreate("CDO.Message")
        $objEmail.From = '"' & $s_FromName & '" <' & $s_FromAddress & '>'
        $objEmail.To = $s_ToAddress
        Local $i_Error = 0
        Local $i_Error_desciption = ""
        If $s_CcAddress <> "" Then $objEmail.Cc = $s_CcAddress
        If $s_BccAddress <> "" Then $objEmail.Bcc = $s_BccAddress
        $objEmail.Subject = $s_Subject
        If StringInStr($as_Body,"<") and StringInStr($as_Body,">") Then
            $objEmail.HTMLBody = $as_Body
        Else
            $objEmail.Textbody = $as_Body & @CRLF
        EndIf
        If $s_AttachFiles <> "" Then
            Local $S_Files2Attach = StringSplit($s_AttachFiles, ";")
            For $x = 1 To $S_Files2Attach[0]
                $S_Files2Attach[$x] = _PathFull ($S_Files2Attach[$x])
                If FileExists($S_Files2Attach[$x]) Then
                    $objEmail.AddAttachment ($S_Files2Attach[$x])
                Else
                    $i_Error_desciption = $i_Error_desciption & @lf & 'File not found to attach: ' & $S_Files2Attach[$x]
                    SetError(1)
                    return 0
                EndIf
            Next
        EndIf
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = $s_SmtpServer
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = $IPPort
    ;Authenticated SMTP
        If $s_Username <> "" Then
            $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
            $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusername") = $s_Username
            $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendpassword") = $s_Password
        EndIf
        If $Ssl Then
            $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
        EndIf
    ;Update settings
        $objEmail.Configuration.Fields.Update
    ; Sent the Message
        $objEmail.Send
        if @error then
            SetError(2)
            return $oMyRet[1]
        EndIf
    EndFunc ;==>_INetSmtpMailCom
    ;
    ;
    ; Com Error Handler
    Func MyErrFunc()
        $HexNumber = Hex($oMyError.number, 8)
        $oMyRet[0] = $HexNumber
        $oMyRet[1] = StringStripWS($oMyError.description,3)
        ConsoleWrite("### COM Error !  Number: " & $HexNumber & "   ScriptLine: " & $oMyError.scriptline & "   Description:" & $oMyRet[1] & @LF)
        SetError(1); something to check for when this function returns
        Return
    EndFunc ;==>MyErrFunc

;~ skrypt wygenerowany przez polski support AutoIT. autoit.xaa.pl

 

 

 

[Arturzt29]

Dzięki, zadziałało

[hehe7]

Do wszystkich którzy mają taki sam problem: sam taki miałem i to nie jest wina kodu tylko biblioteki udf (sprawdzałem coś koło 3-4 i żadna nie działała w końcu znalazłem na jakimś zagranicznym forum tą i ta dobrze działa)